[DISCLAIMER]
I am well aware of the cumulative quality loss when re-encoding mp3 (or any other lossy format). My problem is I have a few MP3 CDs which are encoded with --alt-preset extreme, and my Hi-Fi chokes more than a little bit on them.
[/DISCLAIMER]

I want to re-encode a whole bunch of MP3 using lame. One way of doing it would be to write a Win32 batch file that uses the FOR command to recurse through all the directories and use MADPLAY to decode the files and LAME to re-encode them, storing them in a different place, but still mirroring the directory structure.

Does anyone know of a frontend/software that can already do that?

You can do that with RazorLame (http://www.dors.de/razorlame/index.php). Just select mp3 as input source files and set your desired output directory & command line for lame. And just press encode after that to start transcoding.

Don't forget to check if 'delete source files" is checked or not, you'll probably want to keep the originals ?

Thanks, I should have thought of RazorLame since that's what I use for encoding

Anyway I wrote a batch file to do the job. Just in case anyone is interested here it is (save as relame.cmd or anyother name you like):


@ECHO OFF
REM --------------------------------
SET lame=--alt-preset 128
REM --------------------------------
IF NOT EXIST %1 GOTO no_source
IF [%2]==[] GOTO no_destination
ECHO.
ECHO Using LAME command line: %lame%
ECHO.
FOR /R %1 %%i IN (*.mp3) DO ( MD "%2%%~pi" & lame --mp3input %lame% "%%i" "%2%%~pnxi" )
GOTO end
:no_source
ECHO.
ECHO ERROR: The SOURCE directory cannot be found.
:no_destination
ECHO.
ECHO Syntax: %0 SOURCE DESTINATION
ECHO.
ECHO This batch file will invoke lame to recusively re-encode
ECHO all the files from the SOURCE folder and place them into
ECHO the DESTINATION folder.
ECHO.
ECHO The lame command line can be changed by editing the
ECHO "SET LAME=..." line in this batch file.
ECHO.
:end


This uses on-the-fly decoding/re-encoding within lame. If you prefer to use madplay for decoding,

If you prefer to use MADPLAY for decoding replace the "FOR ..." line with the following:


FOR /R %1 %%i IN (*.mp3) DO ( MD "%2%%~pi" & ( madplay -v -o wave:"%TEMP%%%~ni.wav" "%%i" && lame %lame% "%TEMP%%%~ni.wav" "%2%%~pnxi" ) & DEL "%TEMP%%%~ni.wav" )


This works straightaway from the CD. The only caveat is the non .mp3 files are not copied.

Actually RazorLame would not work for that purpose: it outputs all files in the same directory! :eek:

I have found the following utility which does just the job and preserves the directory structure: it's AudioUtility from http://www.bofa.ru/audioutility.htm Nice!

I haven't used razorlame in a long time but as far as I remmeber there's an option to output to input dir.

Monkey's Audio is a great frontend for this sort of application as well because it allows you to transfer id3 tags based on filename.

I used to think this was great, and it is, but having recently purchased tag & rename, the id3 tags can be written in one quick step.

Monkey is freeware though:D