// progressbar config
// =========================================
$puts(progress_play,'[ ▶]')
$puts(progress_pause,▮▮)
$puts(progress_bar,═)
$puts(progress_length,15)
$puts(seperator,'   ')

// set 4-character filetype
$puts(filetype,$upper(
$if(%__referenced_file%,$cut($ext(%__referenced_file%),4),
$if($stricmp($left(%_path%,4),cdda),CD,$cut($ext(%_path%),4)
))
))

// detect detailed filetype2
$puts(filetype2,$replace($get(filetype),
WAV,[%__codec% ]WAVE,
SND,'Next/Sun',
AC3,Dolby Digital,
CD,Audio CD,
MKA,Matroska[ %__codec%],
OGG,Ogg[ %__codec%],
MP4,MPEG-4[ %__codec%],
M4A,iTunes[ %__codec%],
MP2,MPEG Layer 2,
MP3,MP3[' ('%__lame_version%')'],
AAC,AAC,
WMA,Window'$' Media Audio,
MPC,Musepack,
OFR,OptimFROG,
OFS,OptimFROG DS,
FLA,FLAC,
APE,Monkey''s Audio,
MAC,Monkey''s Audio,
APL,Monkey''s Audio,
WV,WavPack,
SHN,Shorten,
SPX,Speex,
SID,C64 SID-Tune,
MDZ,Soundtracker Module,
S3Z,Screamtracker Module,
ITZ,Impulsetracker Module,
XMZ,Fasttracker II Module,
MO3,Compressed Module,
MOD,Soundtracker Module,
S3M,Screamtracker Module,
XM,Fasttracker II Module,
IT,Impulsetracker Module,
UMX,Unreal Music File,
MTM,Multitracker Module,
TFM,Final Musicsystem
))
$puts(filetype2,$replace($get(filetype2),FLACC,FLAC))


// set quality-info (bitrate, etc.)
$puts(quality,$if2(%__codec_profile%,

$puts(ratio,
$if($or($strstr(%__compression%,Lossy),$stricmp(%codec%,DualStream)),,
$muldiv($info(bitrate),1000,
$div($mul(%samplerate%,$info(bitspersample),$channels()),100)
)))
$ifgreater($get(ratio),0,$ifequal($get(ratio),100,,$get(ratio)'%' compr.)
,[%bitrate%kbit])

[$info(mod_channels) channels]

$if($strcmp($codec(),MP3),' '$if2(%__extrainfo%,CBR)
[' / '$upper($abbr(%__mp3_stereo_mode%))])
))
// -----------------------------------------

// progressbar
$puts(progressbar,
$if(%_length_seconds%,

'◂'
$progress(%_time_elapsed_seconds%,%_length_seconds%,
$get(progress_length),
$if(%_ispaused%,$get(progress_pause),$get(progress_play)),
$get(progress_bar))
'▸ '

$pad_right($muldiv(%_time_elapsed_seconds%,100,%_length_seconds%),3)'%'

,streaming...
))

// time-display
$puts(time,'['$if2(%_time_elapsed%,-:--)['/'%_length%]']'
)

// display statusbar
// =========================================
' '
$get(filetype2)
$get(seperator)
$get(quality)
$get(seperator)
$get(progressbar)
$char(9)
$get(time)
' '