//*******************配置项*******************

//是否显示专辑信息,yes为显示
$puts(s_album,no)

//星颜色个数
$puts(c_starnum,4)
//星颜色枚举
$puts(c_star1,9A6D45)
$puts(c_star2,79A5FF)
$puts(c_star3,FC9DFC)
$puts(c_star4,FCE99D)

//两颜色相同不作渐变
//标题颜色渐变
$puts(ts_title1,EBDED3)
$puts(ts_title2,A5764B)
//艺术家颜色渐变
$puts(ts_artist1,EBDED3)
$puts(ts_artist2,A5764B)
//专辑颜色渐变
$puts(ts_album1,EBDED3)
$puts(ts_album2,A5764B)

//曲目序号颜色
$puts(c_lst,684A2F)
//文件编码颜色
$puts(c_code,684A2F)
//歌曲长度颜色
$puts(c_len,684A2F)
//音轨序号颜色
$puts(c_tkn,684A2F)
//文件年代颜色
$puts(c_date,684A2F)
//'|'颜色1
$puts(c_11,412E1D)
//'|'颜色2
$puts(c_12,684A2F)

//标题最大长度
$puts(len_title,25)
//艺术家最大长度
$puts(len_artist,20)
//专辑最大长度
$puts(len_album,25)

//*******************结束配置*******************

//lstar
$puts(lstar,$get(c_11)|$get(c_12)|$select($add(
$mod(%_time_elapsed_seconds%,$get(c_starnum)),1),
$get(c_star1),$get(c_star2),$get(c_star3),$get(c_star4),
//这里添加星的颜色,用','号隔开
)*)

//title
$puts(title,$transition($caps($if(%isplaying%,
$padcut($substr($padcut(%title%,$get(len_title)),1,
$add($mod(%_time_elapsed_seconds%,$len(%title%)),1)),
$get(len_title)),$padcut(%title%,$get(len_title)))),
$get(ts_title1),$get(ts_title2)))

//artist
$puts(artist,$transition($caps2($if(%artist%,
$padcut(%artist%,$get(len_artist)),
$padcut('未知艺术家',$get(len_artist)))),
$get(ts_artist1),$get(ts_artist2)))

//tracknumber
$puts(tcn,$if($stricmp($get(s_album),yes),$get(lstar)
$if(%tracknumber%,$get(c_tkn)$padcut(%tracknumber%,2),  )))

//album
$puts(album,$if($stricmp($get(s_album),yes),$get(lstar)
$transition($caps($if(%album%,
$padcut(%album%,$get(len_album)),$padcut(%title%,$get(len_album)))),
$get(ts_album1),$get(ts_album2))))

//date
$puts(date,$if(%date%,$get(c_date)$padcut(%date%,6),    ))

//******************实体部分******************

$get(c_lst)%list_index%
$get(lstar) $get(title)
$get(lstar)$get(date)
$get(lstar) $get(artist)
$get(tcn) $get(album)
$tab()
$get(c_code)%codec%
$get(lstar)
$get(c_len)%_length%