Hydrogenaudio Forums > I'm at my wits end, please help!

Full Version: I'm at my wits end, please help!

Hydrogenaudio Forums > Lossless Audio Compression > Lossless / Other Codecs

Pages: 1, 2

zonto

Jan 8 2008, 00:07

OK guys so I've spent the last couple days trying to do this rather complex task. I'm in the process of ripping my entire CD collection and I desperately need help configuring it.

EAC is set up right, I have a plextor premium and Samsung Sh-203b burner (the plextor seems to be better for ripping audio). Anywho this is what I need to do:

1. Rip each album to a total of 3 formats: flac -8 for archiving on external drive, LAME mp3 v0 vbr new for portable compatibility, AND itunesencode4.6 apple lossless to put on my 80gb ipod classic

I don't really feel like changing the gain settings and stuff on the lossless, but figure that I can just load my whole mp3 folder when it's done into mp3gain and do an album max no-clipping setting.

I've tried just about everything but it's so confusing to me that it's getting me nowhere. I've tried wack, flacattack, looked at mareo but got overwhelmed by the .ini, even foobar2000 with just a flac trying to get apple lossless resulted in a .tmp file with no tags...

Can anyone help me out with this? I want to put each rip in a seperate folder on my 415GB D:\ partition.

FLAC: D:\Music\FLAC\%artist\%album\%artist - %album - %tracknumber -%title

Apple Lossless: D:\Music\iTunes\iTunes Music\%artist\%album\%artist - %album - %tracknumber -%title

MP3 -v0: D:\Music\MP3\Rips\%artist\%album\%artist - %album - %tracknumber -%title

I would like the cuesheet and log file with the flac I suppose so that I can burn them later. I also figured that I would keep the flac in separate files rather than an image just in case there's a decent alternative to iPod down the line that I can afford (I got the 80g classic for very very cheap). Is it possible to embed a cuesheet in each flac track file?

Thanks in advance for help, I know it's annoying but I really have tried to do everything I can at this point.

SamHain86

Jan 8 2008, 07:27

QUOTE
apple lossless to put on my 80gb ipod classic
First I'd recommend Rockbox for your iPod classic. I don't know diddly when it comes to which iPod is which, so look here, there is an 80GB video iPod... classic? That way you don't even need to worry about apple lossless, it will play FLAC natively.

QUOTE

1. Rip each album to a total of 3 formats: flac -8 for archiving on external drive, LAME mp3 v0 vbr new for portable compatibility, AND itunesencode4.6 apple lossless to put on my 80gb ipod classic

I don't really feel like changing the gain settings and stuff on the lossless, but figure that I can just load my whole mp3 folder when it's done into mp3gain and do an album max no-clipping setting.

Next go with REACT2 for EAC, Synthetic Soul's modified version. The INI is really easy to configure, I had it configured (initially, but kept messing around because I wasn't working with Syth's mod) in 12 mintues, and I know jack about this stuff (I just recognize patterns and repeat).

REACT natively outputs each type of rip to separate directories, but this behavior can be changed (I have a unique folder structure, and REACT models it perfectly).

It will also apply replaygain to your tracks.

QUOTE

I would like the cuesheet and log file with the flac I suppose so that I can burn them later.

Agreed with and covered with REACT.

QUOTE

I also figured that I would keep the flac in separate file format just in case there's a decent alternative to iPod down the line that I can afford (I got the 80g classic for very very cheap).

I am not reading this right... so I can't help you.

QUOTE

Is it possible to embed a cuesheet in each flac track file?

Not exactly and it is not necessary.

TREX6662k6

Jan 8 2008, 08:32

Rockbox is currently unsupported on the iPod classics due to firmware encryption.

zonto

Jan 8 2008, 09:29

I guess what didn't make sense about the react2 ini is the brackets. Do I need to somehow establish actual folder structure values for things like [personal], etc...?

Does react2 mod also do album art at all? Could someone post a sample react2 mod ini config so I could see a model so to speak of how to set it up? That would help a lot! Thanks for the help, I would totally use rockbox if I had the ipod photo or video but alas couldn't buy them in stores...

zonto

Jan 8 2008, 15:08

OK so I can get it to encode now, still some problems:

1. no embedded cuesheet - I'm guessing this is because I'm not doing a seperate image rip for flac but individual files. Should I just have EAC do a "noncompliant cuesheet" and put it in my FLAC directory?

2. mp3 tags aren't written: I tried default REACT command line which is just -v0 --vbr-new --noreplaygain --nohist, and this as well:

-V 0 --vbr-new --add-id3v2 --pad-id3v2 --ta "%a" --tt "%t" --tl "%g" --ty "%y" --tn "%n" %s %d

With the 1st one it encodes beautifully but no tag info comes up in the folder when I view it...
With the 2nd one react comes up and says metamp3.exe error

3. no album art is downloaded or the program doesn't even work. I got some walmart albumart.exe and pointed react to it and said for it to search by putting a 1 in the .ini, but nothing comes up. Which program should I be using for album art embedding, and does it even with work with non-image ripping?

Thanks for the help so far!

greynol

Jan 8 2008, 15:13

I try not to comment on decisions people make regarding the formats or applications they choose or try to promote one thing over another, but why have you chosen to use both ALAC and flac?

If you're interested in using lossless for archival/backup, your ALAC files will do the job just fine.

QUOTE

Should I just have EAC do a "noncompliant cuesheet" and put it in my FLAC directory?

Yes.

SamHain86

Jan 8 2008, 17:13

For album art to be embedded you need to save it to the same directory where the temporary files are created, if I remember correctly.

I always rip to images, so I can't exactly help when it comes to the track CFG. Also, since I butcher my CFG and INI, I won't be much help. If you like to see my versions.

If you see "> " that means I added those or changed those lines in my INI and CFG.

REACT.INI

CODE

[Settings]
Version=2.0.ssb16h
>	ImageExt=flac
ImageNaming=$cdartist$ - [$year$] $album$
ImageHotKey={F10}
TracksHotKey={F4}
TracksHotVal=+{F5}
VA=Various
CreateAllCuesheets=0
RunCoverDownloader=1
CoverDownloader=C:\Program Files\REACT2\coverdownloader\albumart.exe
EAC=C:\Program Files\Exact Audio Copy\EAC.exe
Tools=C:\Program Files\REACT2\tools
MinimizeCompressionWindow=0
ProcessPriority=1
Sla_Bks_Col_Qst_Bar_Quo_Ast_Lt_Gt=-|-|-||!|'|#|[|]
Test=1

[UserTrackFormats]
Flac=0
Wavpack=0
LameMP3=1
NeroAac=0
iTunesAac=0
OggEnc2=1

[UserOutputNames]
>	RootFolder=G:\MEDIA\CDDA_ARCHIVE
>	OutRoot=@RootFolder@\$genre$\$cdartist$\$album$ [$year$]
>	OutRoot_sndtrk=@RootFolder@\Soundtrack\$album$ [$year$, $cdartist$]
>	ImageDir_Flac=FLAC Lossless Image
>	ImageDir_Wavpack=WavPack Lossless Image
>	ImageDir_MP3=MP3 Image
>	TrackDir_Flac=FLAC Lossless Tracks
>	TrackDir_Wavpack=WavPack Hybrid Tracks
>	TrackDir_MP3=MP3 Tracks
>	TrackDir_AAC=AAC Tracks
>	TrackDir_OGG=OGG Vorbis Tracks
TrackName_SA=$track$ $title$
TrackName_VA=$track$ $title$
TrackName_SA_acdir=$n $~t
TrackName_VA_acdir=$n $~t

[UserSettings]
Debug=0
>	Comment=Ripped by SAM HAIN // EAC-0.99b/REACT2-mod // @curdate@
EmbedCover=1
ReplayGain=1
ApplyAlbumGain=0
AdjustAlbumGain_dB=+3.0
AddCuesheetAG=0
UseWaveGainAG=0
>	Opt_Flac=-8 -V -f
>	Opt_Wavpack=-hh -m
>	Opt_LameMP3=-V2 --vbr-new --noreplaygain
Opt_NeroAac=-lc -q 0.21
Opt_iTunesAac=-d -s 2000
>	Opt_OggEnc2=-q 2.0
>	Opt_Rehash=-none -crc32 -md5 -sha1 -tiger
>	Archive_Tool="C:\Program Files\7-Zip\7z.exe"
>	Archive_Tool_args=a -tzip "@basename@.zip" -mm=Copy
Ver_Flac=1.2.0
Ver_Wavpack=4.41.0
Ver_LameMP3=3.97
Ver_OggEnc2=2.84 libvorbis 1.2.0
Ver_Rehash=1.0.1


[DefaultMetaData]
discnumber=1
totaldiscs=1
discname=

REACT-image.cfg

CODE

@ECHO OFF
CHCP 1252
TITLE "@album@"

REM Copyright © Tycho, 2006
REM
REM ** Ripping to .wav image.
REM **
REM ** To archive a CD as one large "image", you must SET
REM ** ImageExt=... in the REACT.ini file (Press Alt-F2).
REM ** This will set the @ImageExt@ variable. Extensions
REM ** currently supported:  flac, wv, mp3. Set to 'wav'
REM ** for no image archiving (default).
REM **
REM ** Also creates tracks by encoding directly to tracks, using ACDIR.
REM **
REM ** Flac requires flac.exe/metaflac.exe (v1.1.3)
REM ** NeroAac requires NeroAacEnc.exe/NeroAacTag.exe/AacGain.exe.
REM ** OggEnc2 requires OggEnc2.exe/VorbisGain.exe.
REM **
REM ** I prefer applying album gain 92dB to get a reasonable
REM ** volume for my DAP. The RG tags are still relative
REM ** to 89dB SPL, i.e. album gain will be about -3.0dB.

REM ============== Begin Main Script ==================

>	IF NOT @Test@==1 GOTO end_test_part
>		ECHO Oy! You might be using your experimental settings!
>		ECHO Go fix these Variables:
>		ECHO - Test, UserTrackFormats, UserOutputNames, and UserSettings
>		PAUSE
>	:end_test_part


IF @Debug@==1 ECHO ON

IF @various@==0	SET TrackName=@TrackName_SA_acdir@
IF @various@==1	SET TrackName=@TrackName_VA_acdir@

SET add_rg=@ReplayGain@
SET have_cover=0
SET embed_cover=0

IF NOT @ReplayGain@==1 GOTO end_RG
	SET RG_Flac=--replay-gain
	SET RG_MetaFlac=--add-replay-gain
	SET RG_MetaMP3=--replay-gain
:end_RG

IF NOT @ApplyAlbumGain@==1 GOTO end_apply_AG
	SET ApplyAG_MetaMP3=--apply-gain album@AdjustAlbumGain_dB@
	SET ApplyAG_AacGain=/a /o /c /d @AdjustAlbumGain_dB@
	SET add_rg=1
:end_apply_AG


IF EXIST "@cover@" (
	SET have_cover=1
	SET embed_cover=@EmbedCover@
)

IF @various@==0 (
	SET ArtistField=artist
	SET MP3Artist=--artist "@artist@"
) else (
	SET ArtistField=album artist
	SET MP3Artist=--user-text "[album artist]@VA@" --frame "TPE2:@VA@"
)

SET run_wavegain=@UseWaveGainAG@
IF @AddCuesheetAG@==1 SET run_wavegain=1

IF %run_wavegain%==0 GOTO end_wavegain
	SET wg_tmp=wg_%RANDOM%
	@tools@\WaveGain.exe --album "@source@" --exec ECHO '%%ALBUM_GAIN%%'%%ALBUM_PEAK%%'%%ALBUM_NEW_PEAK%%'%%ALBUM_SCALE%%'> %wg_tmp%.txt
	FOR /F "usebackq tokens=1-6 delims='" %%a IN (%wg_tmp%.txt) DO (
		SET album_gain=%%b
		SET album_peak=%%c
		SET album_new_peak=%%d
		SET album_scale=%%e
	)
	ECHO REM REPLAYGAIN_ALBUM_GAIN %album_gain% dB> %wg_tmp%.cue
	ECHO REM REPLAYGAIN_ALBUM_PEAK %album_peak%>> %wg_tmp%.cue
	ECHO REM REPLAYGAIN_ALBUM_SCALE %album_scale%>> %wg_tmp%.cue
	DEL %wg_tmp%.txt
	TYPE "@cuesheet@" >> %wg_tmp%.cue
	MOVE /Y %wg_tmp%.cue "@cuesheet@"
:end_wavegain


REM ** Transfer RG values from Wavgain calculations, instead of recalculation.
IF @UseWaveGainAG@==1 IF %add_rg%==1 (
	SET RG_Flac=-T "replaygain_album_gain=%album_gain% dB" -T "replaygain_album_peak=%album_peak%"
	SET RG_MetaFlac=--set-tag="replaygain_album_gain=%album_gain% dB" --set-tag="replaygain_album_peak=%album_peak%"
	SET RG_Wavpack=-w "replaygain_album_gain=%album_gain% dB" -w "replaygain_album_peak=%album_peak%"
	SET RG_Wavpack_acdir=-w $qreplaygain_album_gain=%album_gain% dB$q -w $qreplaygain_album_peak=%album_peak%$q
	SET RG_MetaMP3=--user-text "[replaygain_album_gain]%album_gain% dB" --user-text "[replaygain_album_peak]%album_peak%"
	SET RG_OggEnc2_acdir=-c $qreplaygain_album_gain=%album_gain% dB$q -c $qreplaygain_album_peak=%album_peak%$q
)

REM ** Apply AlbumGain by using --scale <factor> computed from WaveGain. Only for MP3 and OGG.
IF @UseWaveGainAG@==1 IF @ApplyAlbumGain@==1 (
	SET ApplyAG_Lame=--scale %album_scale%
	SET ApplyAG_MetaMP3=--apply-gain @AdjustAlbumGain_dB@
	SET RG_MetaMP3=--user-text "[replaygain_album_gain]0.0 dB" --user-text "[replaygain_album_peak]%album_new_peak%"
	SET RG_OggEnc2_acdir=--scale %album_scale% -c $qreplaygain_album_gain=0.0 dB$q -c $qreplaygain_album_peak=%album_new_peak%$q
)


REM ---- Image Processing----

>	IF @ImageExt@==wav GOTO end_image_processing

>		TITLE @album@

IF NOT @ImageExt@==flac GOTO end_flac_image
>		SET dest="@OutRoot@\@ImageDir_Flac@"
>		IF "@genre@"=="Soundtrack" SET dest="@OutRoot_sndtrk@\@ImageDir_Flac@"
	IF NOT EXIST %dest% MKDIR %dest%
	IF %embed_cover%==1 SET Cover_tag=--picture="|image/jpeg|||@cover@"
	@tools@\flac.exe @Opt_Flac@ %RG_Flac% %Cover_tag% -T "%ArtistField%=@cdartist@" -T album="@album@" -T totaltracks="@numtracks@" -T date="@year@" -T genre="@genre@" -T comment="@comment@" -T encoding="Flac @Ver_Flac@ @Opt_Flac@" --tag-from-file="cuesheet=@cuesheet@" --tag-from-file="eaclog=@eaclog@" "@source@" -o "@image@"
:end_flac_image



IF NOT @ImageExt@==wv GOTO end_wavpack_image
>		SET dest="@OutRoot@\@ImageDir_Wavpack@"
>		IF "@genre@"=="Soundtrack" SET dest="@ImageDir_Wavpack_sndtrk@"
	IF NOT EXIST %dest% MKDIR %dest%
	@tools@\wavpack.exe @Opt_Wavpack@ %RG_Wavpack% -w "%ArtistField%=@cdartist@" -w album="@album@" -w totaltracks="@numtracks@" -w year="@year@" -w genre="@genre@" -w comment="@comment@" -w encodersettings="Wavpack @Ver_Wavpack@ @Opt_Wavpack@" -w cuesheet="@@cuesheet@" -w eaclog="@@eaclog@" "@source@" "@image@"
:end_wavpack_image


IF NOT @ImageExt@==mp3 GOTO end_lame_image

	SET dest="@ImageDir_MP3@"

	IF "@genre@"=="Soundtrack" SET dest="@ImageDir_MP3_sndtrk@"

	IF NOT EXIST %dest% MKDIR %dest%
	IF %embed_cover%==1 SET Cover_tag=--pict "{3}@cover@"
	@tools@\lame.exe @Opt_LameMP3@ %ApplyAG_Lame% "@source@" "@image@"
	@tools@\metamp3.exe %RG_MetaMP3% %Cover_tag% %MP3Artist% --album "@album@" --track @numtracks@ --year "@year@" --genre "@genre@" --comment "@comment@" --frame TSSE:"LAME @Ver_LameMP3@ @Opt_LameMP3@" "@image@"
	IF @ApplyAlbumGain@==1 @tools@\metamp3.exe %ApplyAG_MetaMP3% "@image@"
:end_lame_image

>	ECHO - >> "@eaclog@"
>	ECHO - >> "@eaclog@"
>	ECHO     ---- Appended Data from Image Processing ---- >> "@eaclog@"
>	ECHO - >> "@eaclog@"
>	ECHO - >> "@eaclog@"

>	ECHO MD5 hash of Source audio: "@source@" >> "@eaclog@"
>	shntool hash "@source@" >> "@eaclog@"
>	ECHO - >> "@eaclog@"
>	ECHO - >> "@eaclog@"

>	ECHO MD5 hash of Image audio: "@image@" >> "@eaclog@"
>	shntool hash "@image@" >> "@eaclog@"
>	ECHO - >> "@eaclog@"
>	ECHO - >> "@eaclog@"

>	ECHO Hash calculations on: "@image@"
>	ECHO Hash calculations on: "@image@" >> "@eaclog@"
>	@tools@\rehash.exe @Opt_Rehash@ "@image@" >> "@eaclog@"

>	ECHO Moving Output to: %dest%
>	MOVE /Y "@image@" %dest%
>	MOVE /Y "@cuesheet@" %dest%
>	MOVE /Y "@eaclog@" %dest%
IF %have_cover%==1 COPY /Y "@cover@" %dest%\"@basename@.jpg"
PUSHD %dest%
>	ECHO Creating Archive
>	@Archive_Tool@ @Archive_Tool_args@
POPD

:end_image_processing



REM ---- Track Processing ----


IF NOT @Flac@==1 GOTO end_flac_tracks
>		SET dest="@OutRoot@\@TrackDir_Flac@"

>		IF "@genre@"=="Soundtrack" SET dest="@OutRoot_sndtrk@\@TrackDir_Flac@"

	IF NOT EXIST %dest% MKDIR %dest%
	PUSHD %dest%
		IF @various@==1 SET VA_tag=-T $qalbum artist=@VA@$q
		IF %embed_cover%==1 SET Cover_tag=--picture=$#x
		@tools@\acdir.exe --overwrite --output "%TrackName%.flac" --extra-opt "|image/jpeg|||@cover@" --pipe "TITLE $n/$N flac $#T & @tools@\flac.exe @Opt_Flac@ %Cover_tag% %VA_tag% -T artist=$#a -T album=$#T -T title=$#t -T tracknumber=$n/$N -T date=$q@year@$q -T genre=$q@genre@$q -T comment=$q@comment@$q -T encoding=$qFlac @Ver_Flac@ @Opt_Flac@$q - -o $#o" "@sourcecuesheet@"
		IF %add_rg%==1 @tools@\Glob.exe -v -c @tools@\metaflac.exe %RG_MetaFlac% *.flac
		COPY /Y "@eaclog@" "EAClog.txt"
		IF %have_cover%==1 COPY /Y "@cover@" "folder.jpg"
		IF EXIST "@albumfile@.[*].cue" COPY /Y "@albumfile@.[*].cue" .
		@tools@\rehash.exe @Opt_Rehash@ "*.flac" > "@basename@ @TrackDir_Flac@.hash.txt"
	POPD
:end_flac_tracks


IF NOT @Wavpack@==1 GOTO end_wavpack_tracks
	SET dest="@OutRoot@\@TrackDir_Wavpack@"

	IF "@genre@"=="Soundtrack" SET dest="@OutRoot_sndtrk@\@TrackDir_Wavpack@"

	IF NOT EXIST %dest% MKDIR %dest%
	PUSHD %dest%
		IF @various@==1 SET VA_tag=-w $qalbum artist=@VA@$q
		@tools@\acdir.exe --overwrite --output "%TrackName%.wv" --pipe "@tools@\wavpack.exe @Opt_Wavpack@ %RG_Wavpack_acdir% %VA_tag% -w artist=$#a -w album=$#T -w title=$#t -w track=$n/$N -w year=$q@year@$q -w genre=$q@genre@$q -w comment=$q@comment@$q -w encodersettings=$qWavpack @Ver_Wavpack@ @Opt_Wavpack@$q - $#o" "@sourcecuesheet@"
		IF @ReplayGain@==1 IF @UseWaveGainAG@==0 @tools@\wvgain.exe -a *.wv
		COPY /Y "@eaclog@" "EAClog.txt"
		IF %have_cover%==1 COPY /Y "@cover@" "folder.jpg"
		IF EXIST "@albumfile@.[*].cue" COPY /Y "@albumfile@.[*].cue" .
		@tools@\rehash.exe @Opt_Rehash@ "*.*" > "@basename@ @TrackDir_Wavpack@.hash.txt"
	POPD
	TITLE "@album@"
:end_wavpack_tracks


IF NOT @LameMP3@==1 GOTO end_lame_tracks
	SET dest="@OutRoot@\@TrackDir_MP3@"

	IF "@genre@"=="Soundtrack" SET dest="@OutRoot_sndtrk@\@TrackDir_MP3@"

	IF NOT EXIST %dest% MKDIR %dest%
	PUSHD %dest%
		IF @various@==1 SET VA_tag=--user-text $q[album artist]@VA@$q --frame $qTPE2:@VA@$q
		IF %embed_cover%==1 SET Cover_tag=--pict $#x
		@tools@\acdir.exe --overwrite --output "%TrackName%.mp3" --extra-opt "{3}@cover@" --pipe "TITLE $n/$N mp3 $#T & @tools@\lame.exe @Opt_LameMP3@ %ApplyAG_Lame% - $#o & @tools@\metamp3.exe %Cover_tag% %VA_tag% --artist $#a --album $#T --title $#t --track $n/$N --year $q@year@$q --genre $q@genre@$q --comment $q@comment@$q --frame TENC:$q%USERNAME%$q --frame TSSE:$qLAME @Ver_LameMP3@ @Opt_LameMP3@$q $#o" "@sourcecuesheet@"
		IF %add_rg%==1 @tools@\metamp3.exe %RG_MetaMP3% *.mp3
		IF @ApplyAlbumGain@==1 @tools@\metamp3.exe %ApplyAG_MetaMP3% *.mp3
		REM COPY /Y "@eaclog@" "EAClog.txt"
		@tools@\rehash.exe @Opt_Rehash@ "*.mp3" > "@basename@ @TrackDir_MP3@.hash.txt"
		IF %have_cover%==1 COPY /Y "@cover@" "folder.jpg"
	POPD
:end_lame_tracks


IF NOT @NeroAac@==1 GOTO end_nero_aac_tracks
	SET dest="@OutRoot@\@TrackDir_AAC@"

	IF "@genre@"=="Soundtrack" SET dest="@OutRoot_sndtrk@\@TrackDir_AAC@"

	IF NOT EXIST %dest% MKDIR %dest%
	PUSHD %dest%
		IF @various@==1 SET VA_tag=--albumArtist $q@VA@$q --compilation true
		IF %embed_cover%==1 SET Cover_tag=--artwork $#x
		@tools@\acdir.exe --overwrite --output "%TrackName%.m4a" --extra-opt "@cover@" --pipe "TITLE $n/$N aac $#T & @tools@\neroAacEnc.exe @Opt_NeroAac@ -ignorelength -if - -of $#o & @tools@\AtomicParsley.exe $#o -o REACT_tmp.m4a %Cover_tag% %VA_tag% --artist $#a --album $#T --tracknum $n/$N --title $#t --year $q@year@$q --genre $q@genre@$q --comment $q@comment@$q --encodingTool $qneroAacEnc @Ver_NeroAac@ @Opt_NeroAac@$q & MOVE /Y REACT_tmp.m4a $#o" "@sourcecuesheet@"
		IF @ApplyAlbumGain@==1 @tools@\aacgain.exe %ApplyAG_AacGain% *.m4a > gainlog.txt
		@tools@\rehash.exe @Opt_Rehash@ "*.*" > "@basename@ @TrackDir_AAC@.hash.txt"
		IF %have_cover%==1 COPY /Y "@cover@" "folder.jpg"
	POPD
:end_nero_aac_tracks


IF NOT @OggEnc2@==1 GOTO end_oggenc_tracks
	SET dest="@OutRoot@\@TrackDir_OGG@"

	IF "@genre@"=="Soundtrack" SET dest="@OutRoot_sndtrk@\@TrackDir_OGG@"

	IF NOT EXIST %dest% MKDIR %dest%
	PUSHD %dest%
		IF @various@==1 SET VA_tag=-c $qalbum artist=@VA@$q
		@tools@\acdir.exe --overwrite --output "%TrackName%.ogg" --pipe "TITLE $n/$N ogg $#T & @tools@\oggenc2.exe @Opt_OggEnc2@ %RG_OggEnc2_acdir% %VA_tag% -c artist=$#a -c album=$#T -c title=$#t -c tracknumber=$n/$N -c date=$q@year@$q -c genre=$q@genre@$q -c comment=$q@comment@$q -c encoding=$qOggEnc @Ver_OggEnc2@ @Opt_OggEnc2@$q - -o $#o" "@sourcecuesheet@"
		IF @ReplayGain@==1 IF @UseWaveGainAG@==0 @tools@\vorbisgain.exe *.ogg
		@tools@\rehash.exe @Opt_Rehash@ "*.ogg" > "@basename@ @TrackDir_OGG@.hash.txt"
		IF %have_cover%==1 COPY /Y "@cover@" "folder.jpg"
	POPD
:end_oggenc_tracks

IF EXIST "@cover@" COPY /Y "@cover@" "@OutRoot@\@album@.jpg"

REM ================ End Main Script ===================


IF @Debug@==1 (
	PAUSE
	EXIT
)

REM ** Cleanup

DEL "@source@"
DEL "@eaclog@"
DEL "@cuesheet@"
DEL "@albumfile@.[*].cue"
DEL "@cover@"

REM ** Delete this .bat file:
DEL %0

You'll have lots of questions, I realize. PM if you have any specific questions concerning your INI or CFG or mine.

zonto

Jan 9 2008, 01:27

EDIT: nm fixed one problem

Any ideas how to get cover art to be embedded in the ALAC files? Nothing shows up in iTunes, nor is there any window that comes up to select an image.

Also, how do I know if any replay or album gain was done to the files?

Synthetic Soul

Jan 9 2008, 06:04

iTunesEncode has the -r switch to add album art.

I'm not sure whereabouts you are with your REACT setup now. Yesterday I did work on an amended INI and CFG (based on the files included in my mod's zip file) for you but got distracted. I have updated them to include embedding album art, but they may still be lacking. Here they are anyway, even if it's just for reference sake:

REACT.ini:

CODE

[Settings]
Version=2.0.ssb16
ImageExt=wav
ImageNaming=$artist$ - [$year$] $album$
ImageHotKey={F10}
TracksHotKey={F4}
TracksHotVal=+{F5}
VA=Various Artists
CreateAllCuesheets=1
RunCoverDownloader=1
CoverDownloader=C:\Program Files\REACT2\coverdownloader\albumart.exe
CoverDownloaderXUI=0
EAC=C:\Program Files\Exact Audio Copy\EAC.exe
Tools=C:\Program Files\REACT2\tools
MinimizeCompressionWindow=1
ProcessPriority=1
Sla_Bks_Col_Qst_Bar_Quo_Ast_Lt_Gt=-|-|-||!|'|#|[|]
Test=0

[UserTrackFormats]
Flac=1
Wavpack=0
Tak=0
LameMP3=1
NeroAac=0
iTunesAac=0
OggEnc2=0
iTunesLossless=1

[UserOutputNames]
OutRoot=D:\Music
ImageDir_Flac=@OutRoot@\FLAC-images\$cdartist$
ImageDir_Wavpack=@OutRoot@\WV-images\$cdartist$
ImageDir_Tak=@OutRoot@\TAK-images\$cdartist$
ImageDir_MP3=@OutRoot@\MP3-images\$cdartist$
TrackDir_Flac=@OutRoot@\FLAC\$cdartist$\$album$
TrackDir_Wavpack=@OutRoot@\WV\$cdartist$\$album$
TrackDir_Tak=@OutRoot@\TAK\$cdartist$\$album$
TrackDir_MP3=@OutRoot@\MP3\Rips\$cdartist$\$album$
TrackDir_AAC=@OutRoot@\AAC\$cdartist$\$album$
TrackDir_OGG=@OutRoot@\OGG\$cdartist$\$album$
TrackDir_ALS=@OutRoot@\iTunes\iTunes Music\$cdartist$\$album$
TrackName_SA=$cdartist$ - $album$ - $track$ - $title$
TrackName_VA=$cdartist$ - $album$ - $track$ - $title$ [$artist$]
TrackName_SA_acdir=$~A - $~T - $n - $~t
TrackName_VA_acdir=$~A - $~T - $n - $~t [$~a]

[UserSettings]
Debug=0
Comment=Created with EAC/REACT2, @curdate@
EmbedCover=1
ReplayGain=0
ApplyAlbumGain=0
AdjustAlbumGain_dB=+3.0
AddCuesheetAG=0
UseWaveGainAG=0
Opt_Flac=-8 -f
Opt_Wavpack=-hmy
Opt_Tak=-pN -overwrite
Opt_LameMP3=-V0 --vbr-new --noreplaygain --nohist
Opt_NeroAac=-lc -q 0.21
Opt_iTunesAac=-d -s 2000
Opt_OggEnc2=-q 3.0
Ver_Flac=1.2.0
Ver_Wavpack=4.40
Ver_Tak=1.0.1
Ver_LameMP3=3.97
Ver_NeroAac=1.0.0.2
Ver_OggEnc2=2.83 Lancer aoTuV b5

[DefaultMetaData]
discnumber=1
totaldiscs=1
discname=

REACT-track.cfg:

CODE

@ECHO OFF
CHCP 1252 | PROMPT
TITLE @track@/@numtracks@ - "@album@"

REM Copyright © Tycho, 2006
REM
REM ** Create compressed audio tracks from ripped .wav tracks.
REM **
REM ** You may consider using image mode (F10)
REM ** as it supports creating tracks via acdir.exe,
REM ** and post-processing will always work (see below).
REM **
REM ** Flac requires flac.exe/metaflac.exe (v1.1.3)
REM ** NeroAac requires NeroAacEnc.exe/NeroAacTag.exe/AacGain.exe.
REM ** OggEnc2 requires OggEnc2.exe/VorbisGain.exe.
REM **
REM ** I prefer applying album gain 92dB to get a reasonable
REM ** volume for my DAP. The RG tags are still relative
REM ** to 89dB SPL, i.e. album gain will be about -3.0dB.


REM ============== Begin Main Script ==================


IF @Debug@==1 ECHO ON

REM ** Workaround for multi-processing, added by nago.
ECHO > processing[@track@].tmp

REM ** Create Disc-related tags if we have a set

REM If a disc name has been provided
IF "@discname@" EQU "" GOTO end_discname
SET discName=discname
SET discName=@%discname%@
IF "@discname@" EQU "%discName%" GOTO end_discname

    REM Set tagging switches
    SET Disc_Flac=-T "discname=@discname@"
    SET Disc_Wavpack=-w "discname=@discname@"
    REM SET Disc_MP3=--frame TSST:"@discname@"
    SET Disc_MP3=--frame "TXXX[setsubtitle]:@discname@"
    SET Disc_OggEnc2=-c "discname=@discname@"
    SET Disc_Tak=-t "discname=@discname@"

    REM Add disc name to folder path
    SET trackDir=%trackDir%\$discname$

    GOTO :end_discnumber

:end_discname

REM Ensure that we have numeric values
SET /A discNumber = @discnumber@ + 0
SET /A totalDiscs = @totaldiscs@ + 0

REM IF a valid disc number and total number of discs has been provided
IF %totalDiscs% LEQ 1 GOTO :end_discnumber
IF %discNumber% LEQ 0 GOTO :end_discnumber

    REM Set tagging switches
    SET Disc_Flac=-T "discnumber=@discnumber@" -T "totaldiscs=@totaldiscs@"
    SET Disc_Wavpack=-w "discnumber=@discnumber@" -w "totaldiscs=@totaldiscs@"
    SET Disc_MP3=--frame TPOS:"@discnumber@/@totaldiscs@"
    SET Disc_NeroAac=--disk "@discnumber@/@totaldiscs@"
    SET Disc_OggEnc2=-c "discnumber=@discnumber@" -c "totaldiscs=@totaldiscs@"
    SET Disc_Tak=-t "discnumber=@discnumber@" -t "totaldiscs=@totaldiscs@"
    SET Disc_iTunes=-j @discnumber@ -k @totaldiscs@

    REM Add disc number to folder path
    SET trackDir=%trackDir%\Disc @discnumber@

:end_discnumber


SET TrackDir_Flac="@TrackDir_Flac@%trackDir%"
SET TrackDir_Wavpack="@TrackDir_Wavpack@%trackDir%"
SET TrackDir_MP3="@TrackDir_MP3@%trackDir%"
SET TrackDir_AAC="@TrackDir_AAC@%trackDir%"
SET TrackDir_OGG="@TrackDir_OGG@%trackDir%"
SET TrackDir_Tak="@TrackDir_Tak@%trackDir%"
SET TrackDir_ALS="@TrackDir_ALS@%trackDir%"

SET TrackName=@trackname@

SET have_cover=0
SET embed_cover=0

IF EXIST "@cover@" (
    SET have_cover=1
    SET embed_cover=@EmbedCover@
)




REM ---- Track ----


IF NOT @Flac@==1 GOTO end_flac_tracks
    IF NOT EXIST %TrackDir_Flac% MKDIR %TrackDir_Flac%
    PUSHD %TrackDir_Flac%
        IF @various@==1 SET VA_tag=-T "album artist=@VA@"
        IF %embed_cover%==1 SET Cover_tag=--picture="|image/jpeg|||@cover@"
        ECHO ON
        @tools@\flac.exe @Opt_Flac@ %Cover_tag% %VA_tag% %Disc_Flac% -T artist="@artist@" -T album="@album@" -T tracknumber="@track@/@numtracks@" -T title="@title@" -T date="@year@" -T genre="@genre@" -T comment="@comment@" -T encoded-by="%USERNAME%" -T encoding="Flac @Ver_Flac@ @Opt_Flac@" "@source@" -o "%TrackName%.flac"
        @ECHO OFF
        IF %have_cover%==1 IF NOT EXIST folder.jpg COPY "@cover@" folder.jpg
    POPD
:end_flac_tracks


IF NOT @Wavpack@==1 GOTO end_wavpack_tracks
    IF NOT EXIST %TrackDir_Wavpack% MKDIR %TrackDir_Wavpack%
    PUSHD %TrackDir_Wavpack%
        IF @various@==1 SET VA_tag=-w "album artist=@VA@"
        ECHO ON
        @tools@\wavpack.exe @Opt_Wavpack@ %VA_tag% %Disc_Wavpack% -w artist="@artist@" -w album="@album@" -w track="@track@/@numtracks@" -w title="@title@" -w year="@year@" -w genre="@genre@" -w comment="@comment@" -w encodedby="%USERNAME%" -w encodersettings="Wavpack @Ver_Wavpack@ @Opt_Wavpack@" "@source@" "%TrackName%.wv"
        @ECHO OFF
        IF %have_cover%==1 IF NOT EXIST folder.jpg COPY "@cover@" folder.jpg
        TITLE @track@/@numtracks@ - "@album@"
    POPD
:end_wavpack_tracks


IF NOT @Tak@==1 GOTO end_tak_tracks
    IF NOT EXIST %TrackDir_Tak% MKDIR %TrackDir_Tak%
    PUSHD %TrackDir_Tak%
        IF @various@==1 SET VA_tag=-t "album artist=@VA@"
        ECHO ON
        @tools@\takc.exe -e -overwrite @Opt_Tak@ "@source@" "%TrackName%.tak"
        @tools@\tag.exe %VA_tag% %Disc_Tak% -t artist="@artist@" -t album="@album@" -t track="@track@/@numtracks@" -t title="@title@" -t year="@year@" -t genre="@genre@" -t comment="@comment@" -t encodedby="%USERNAME%" -t encodersettings="TAK @Ver_Tak@ @Opt_Tak@" "%TrackName%.tak"
        @ECHO OFF
        IF %have_cover%==1 IF NOT EXIST folder.jpg COPY "@cover@" folder.jpg
        TITLE @track@/@numtracks@ - "@album@"
    POPD
:end_tak_tracks


IF NOT @LameMP3@==1 GOTO end_lame_tracks
    IF NOT EXIST %TrackDir_MP3% MKDIR %TrackDir_MP3%
    PUSHD %TrackDir_MP3%
        IF @various@==1 SET VA_tag=--user-text "[album artist]@VA@" --frame "TPE2:@VA@"
        IF %embed_cover%==1 SET Cover_tag=--pict "{3}@cover@"
        ECHO ON
        @tools@\lame.exe @Opt_LameMP3@ "@source@" "%TrackName%.mp3"
        @tools@\metamp3.exe %Cover_tag% %VA_tag% %Disc_MP3% --artist "@artist@" --album "@album@" --track @track@/@numtracks@ --title "@title@" --year "@year@" --genre "@genre@" --comment "@comment@" --frame TENC:"%USERNAME%" --frame TSSE:"LAME @Ver_LameMP3@ @Opt_LameMP3@" "%TrackName%.mp3"
        @ECHO OFF
        IF %have_cover%==1 IF NOT EXIST folder.jpg COPY "@cover@" folder.jpg
    POPD
:end_lame_tracks


IF NOT @iTunesAac@==1 GOTO end_itunes_aac_tracks
    IF NOT EXIST %TrackDir_AAC% MKDIR %TrackDir_AAC%
    PUSHD %TrackDir_AAC%
        IF %embed_cover%==1 SET Cover_tag=-r "@cover@"
        ECHO ON
        @tools@\iTunesEncode.exe @Opt_iTunesAac@ -e "AAC Encoder" %Cover_tag% -x @various@ -a "@artist@" -l "@album@" -n "@track@" -m "@numtracks@" -t "@title@" -y "@year@" -g "@genre@" -c "@comment@" -i "@source@" -o "%TrackName%.m4a"
        @ECHO OFF
        IF %have_cover%==1 IF NOT EXIST folder.jpg COPY "@cover@" folder.jpg
    POPD
    GOTO end_nero_aac_tracks
:end_itunes_aac_tracks

IF NOT @NeroAac@==1 GOTO end_nero_aac_tracks
    IF NOT EXIST %TrackDir_AAC% MKDIR %TrackDir_AAC%
    PUSHD %TrackDir_AAC%
        IF @various@==1 SET VA_tag=--albumArtist "@VA@" --compilation true
        IF %embed_cover%==1 SET Cover_tag=--artwork "@cover@"
        ECHO ON
        @tools@\neroAacEnc.exe @Opt_NeroAac@ -if "@source@" -of "%TrackName%.m4a"
        @tools@\AtomicParsley.exe "%TrackName%.m4a" -o REACT_tmp.m4a %Cover_tag% %VA_tag% %Disc_NeroAac% --artist "@artist@" --album "@album@" --tracknum "@track@/@numtracks@" --title "@title@" --year "@year@" --genre "@genre@" --comment "@comment@" --encodingTool "neroAacEnc @Ver_NeroAac@ @Opt_NeroAac@"
        @ECHO OFF
        MOVE /Y REACT_tmp.m4a "%TrackName%.m4a"
        IF %have_cover%==1 IF NOT EXIST folder.jpg COPY "@cover@" folder.jpg
    POPD
:end_nero_aac_tracks


IF NOT @OggEnc2@==1 GOTO end_oggenc_tracks
    IF NOT EXIST %TrackDir_OGG% MKDIR %TrackDir_OGG%
    PUSHD %TrackDir_OGG%
        IF @various@==1 SET VA_tag=-c "album artist=@VA@"
        ECHO ON
        @tools@\oggenc2.exe @Opt_OggEnc2@ %VA_tag% %Disc_OggEnc2% -c artist="@artist@" -c album="@album@" -c tracknumber="@track@/@numtracks@" -c title="@title@" -c date="@year@" -c genre="@genre@" -c comment="@comment@" -c encoded-by="%USERNAME%" -c encoding="OggEnc @Ver_OggEnc2@ @Opt_OggEnc2@" "@source@" -o "%TrackName%.ogg"
        @ECHO OFF
        IF %have_cover%==1 IF NOT EXIST folder.jpg COPY "@cover@" folder.jpg
    POPD
:end_oggenc_tracks


IF NOT @iTunesLossless@==1 GOTO end_itunes_lossless_tracks
    IF NOT EXIST %TrackDir_ALS% MKDIR %TrackDir_ALS%
    PUSHD %TrackDir_ALS%
        IF %embed_cover%==1 SET Cover_tag=-r "@cover@"
        ECHO ON
        @tools@\iTunesEncode.exe -e "Lossless Encoder" %Cover_tag% %Disc_iTunes% -x @various@ -a "@artist@" -l "@album@" -n "@track@" -m "@numtracks@" -t "@title@" -y "@year@" -g "@genre@" -c "@comment@" -i "@source@" -o "%TrackName%.m4a"
        @ECHO OFF
        IF %have_cover%==1 IF NOT EXIST folder.jpg COPY "@cover@" folder.jpg
    POPD
:end_itunes_lossless_tracks


REM ** Delete the source .wav
DEL "@source@"

REM ** More multiprocessing workaround --nago
DEL processing[@track@].tmp


REM ---- Post-processing ----


rem ** Scan and compute ReplayGain and add cover picture for supported formats.
rem ** NB: The following will only work if at least the last track is selected,
rem ** and it is a regular audio track.

IF NOT @track@==@numtracks@ GOTO end_post_process

    REM ** More multiprocessing. Last edit. --nago
    :checktmp
    IF NOT EXIST processing[*].tmp GOTO allProcsClear
      ECHO Waiting for all other processes to clear...
      ECHO If REACT hangs here and there are no other tracks being encoded,
      ECHO please delete all processing[#].tmp files in
      ECHO "@sourcedir@"
      PING 1.1.1.1 -n 1 -w 10000 >NUL
    GOTO checktmp
    :allProcsClear

    SET add_rg=@ReplayGain@
    SET aac_enc=@NeroAac@
    IF @iTunesAac@==1 SET aac_enc=1

    IF NOT @ReplayGain@==1 GOTO end_RG
        SET RG_MetaFlac=--add-replay-gain
        SET RG_MetaMP3=--replay-gain
    :end_RG

    IF NOT @ApplyAlbumGain@==1 GOTO end_apply_AG
        SET RG_MetaMP3=--apply-gain album@AdjustAlbumGain_dB@
        SET RG_AacGain=/a /o /c /d @AdjustAlbumGain_dB@
        SET add_rg=1
    :end_apply_AG


    REM ** Audio Formats:

    IF @Flac@==1 (
        PUSHD %TrackDir_Flac%
            IF %add_rg%==1 @tools@\Glob.exe -v -c @tools@\metaflac.exe %RG_MetaFlac% *.flac
            COPY /Y "@eaclog@" "$cdartist$ - $album$.log"
            COPY /Y "@albumfile@.[mg].cue" "$cdartist$ - $album$.cue"
        POPD
    )

    IF @Wavpack@==1 (
        PUSHD %TrackDir_Wavpack%
            IF %add_rg%==1 @tools@\wvgain.exe -a *.wv
            REM COPY /Y "@eaclog@" "EAClog.txt"
        POPD
    )

    IF @LameMP3@==1 (
        PUSHD %TrackDir_MP3%
            IF %add_rg%==1 @tools@\metamp3.exe %RG_MetaMP3% *.mp3
            REM COPY /Y "@eaclog@" "EAClog.txt"
        POPD
    )

    IF %aac_enc%==1 (
        PUSHD %TrackDir_AAC%
            IF %add_rg%==1 @tools@\aacgain.exe %RG_AacGain% *.m4a > "gainlog.txt"
            REM COPY /Y "@eaclog@" "EAClog.txt"
        POPD
    )

    IF @OggEnc2@==1 (
        PUSHD %TrackDir_OGG%
            IF %add_rg%==1 @tools@\vorbisgain.exe -a *.ogg
            REM COPY /Y "@eaclog@" "EAClog.txt"
        POPD
    )


    REM ** Cleanup

    DEL "@eaclog@"
    DEL "@albumfile@.[*].cue"
    DEL "@cover@"

:end_post_process


REM ================ End Main Script ===================


IF @Debug@==1 (
    PAUSE
    EXIT
)

REM ** Delete this .bat file:
DEL %0

NB: It is possible for you to embed the cuesheet in each FLAC file but tagging a track file with full album information seems a little confusing. I certainly wouldn't use a CUESHEET tag or FLAC meta block. If you insist then I would suggest using a bespoke tag, like ALBUM CUESHEET or something.

Also, it may be worth updating to Album Art XUI and amending the INI accordingly. Not sure if you have already or not.

zonto

Jan 9 2008, 10:37

Thank you so much for your help Synthetic Soul!

Yeah, I kind of realized it would be pointless to do that ^^ so I decided just to stick with ALAC for the time being. I didn't think about doing a separate lossless command in the config file, so thanks for coding that for me. I will try this when I get home tonight.

I got it to encode the ALAC and LAME mp3 last night, with the correct tags. I just need to get embedded album art working, and figure out what to do with replay and album gain. I suppose it would be cool to have all the albums gained to the same target db level for ipod playback so I don't have to constantly reach for the volume control. I was wondering if I do that and then later convert them back to WAV to burn a copy of the CD if the gain things will go away though and it will be back to the normal CD volume so to speak. I've never really understood the details of that process. Would that be worth it to do the album gain? Is that 92 db level the right target to shoot for?

WAIT! So to do album art do I need to rip in image mode and not track mode then? And from reading it seems as though since Apple Lossless isn't quite the same as AAC then it won't work with any gain settings?

Synthetic Soul

Jan 9 2008, 11:44