// *** ALIGNMENT VARIABLES ***
$puts(imgwmax,200)
$puts(rowheight,17)
$puts(calcimgh,$mul(%_itemcount%,$get(rowheight)))
$puts(imgw,
$if($fileexists($get(albumartsrc)),
$if($greater($get(calcimgh),$get(imgwmax)),$get(imgwmax),$get(calcimgh))
,0))
$puts(rightpad,$sub(%_width%,$get(imgw),10))

$puts(colpad,10)
$puts(colw,20)
$puts(colwtrackno,25)
$puts(textleft,$if($greater(%_itemcount%,1),$add($add($get(leftpad),0),$get(colpad)),$get(colpad)))
$puts(aligntrackno,$alignabs($get(textleft),-4,$get(colwtrackno),25,center,middle))
$puts(aligntrack,$alignabs($add($get(textleft),$get(colwtrackno)),0,$sub(%_width%,$add($add($get(textleft),$get(colwtrackno)),35)),$get(rowheight),left,middle))
$puts(aligntime,)

// *** ALBUM ART DISPLAY & PNG OVERLAY ***
$if($and($fileexists($get(albumartsrc)),$greater(%_itemcount%,1)),
$imageabs2($get(imgw),$get(imgw),,$mul($get(rowheight),$sub(%tracknumber%,1)),$get(imgw),$get(rowheight),$get(rightpad),,$get(albumartsrc),KEEPASPECT)
$imageabs2($get(imgw),$get(imgw),,$mul($get(rowheight),$sub(%tracknumber%,1)),$get(imgw),$get(rowheight),$get(rightpad),,$get(albumartoverlay),NOKEEPASPECT ALPHA-50)
,)



// *** ALTERNATE ROW COLOURS ***
$if($greater($mod(%list_index%,2),0),
$drawrect($get(textleft),0,$sub(%_width%,$add($get(imgwmax),24)),0,brushcolor-$get(colorRowBg1) pencolor-$get(colorRowBg1)),
$drawrect($get(textleft),0,$sub(%_width%,$add($get(imgwmax),24)),0,brushcolor-$get(colorRowBg2) pencolor-$get(colorRowBg2))
)

// *** DRAW SELECTED, PLAYING AND FOCUSED BOXES ***
$if($or(%_selected%,%isplaying%),$drawrect($get(textleft),0,$sub(%_width%,$add($get(imgwmax),24)),0,brushcolor-$get(colorSelectedBg) pencolor-null))
$if(%_focused%,$drawrect($get(textleft),0,$sub(%_width%,$add($get(imgwmax),24)),0,brushcolor-null pencolor-80-80-80))
$if(%isplaying%,$drawrect($get(textleft),0,$sub(%_width%,$add($get(imgwmax),24)),0,brushcolor-null pencolor-0-0-0))
$if($or(%_selected%,%isplaying%),$textcolor(SYSCOL-9),$textcolor(SYSCOL-8))

// *** TRACK NO. COL ***
$if($or(%_selected%,%isplaying%),,
$get(aligntrackno)
$get(fontTrackNumber)
$if($strstr(%genre%,Classical),$roman(%tracknumber%),%tracknumber%))

// *** PROGRESS BAR ***
$if(%isplaying%,
$padding($add($get(textleft),8),0)
$puts(progress,$muldiv(%playback_time_seconds%,$sub(%_width%,$add($get(imgwmax),30)),%length_seconds%))
$ifgreater($get(progress),0,
$drawrect(-7,1,$get(progress),15,brushcolor-$get(colorProgressBar) pencolor-null)
,)
)

// *** NORMAL PLAYLIST ***
// Determine if Various Artists album based on filename (VA, OST, DJ Kicks)
$if($or($strstr(%album artist%,Various),$strcmp($substr(%album%,1,3),VA )),

// *** VARIOUS ALBUMS ***
$if($or(%_selected%,%isplaying%),
$get(aligntrack)
$get(fontPlayingArtist)
%artist% -
$get(fontPlayingTitle)
%title%
,

// When Not Selected
$get(aligntrack)
$if($and($strcmp($get(HighlightTracksMissingReplaygain),1),$not(%__replaygain_album_gain%)),$get(fontTitleMissingRG),$get(fontTitle))
%title%
$alignabs($add($get(textleft),$get(colwtrackno)),0,$sub(%_width%,$add($add($get(textleft),$get(colwtrackno)),145)),$get(rowheight),right,middle)
%artist% s
),

// *** NORMAL ALBUMS ***
$get(aligntrack)
$if($or(%_selected%,%isplaying%),
$get(fontPlayingArtist)
%artist% -
$get(fontPlayingTitle)
%title%
,
$if($and($strcmp($get(HighlightTracksMissingReplaygain),1),$not(%__replaygain_album_gain%)),$get(fontTitleMissingRG),$get(fontTitle))
%title%
))