I'm not totally following what you've done.. anyways, here's the modified config file for you, just select all below text in the codebox and replace all contents in the "REACT-track.cfg" file in your REACT install folder:
@ECHO OFF
CHCP 1252 | PROMPT
TITLE @track@/@numtracks@ - "@album@"
REM Copyright © Tycho, 2006
REM
REM ** Create compressed audio tracks from ripped .wav tracks.
REM **
REM ** You may consider using image mode (F10)
REM ** as it supports creating tracks via acdir.exe,
REM ** and post-processing will always work (see below).
REM **
REM ** Flac requires flac.exe/metaflac.exe (v1.1.3)
REM ** NeroAac requires NeroAacEnc.exe/NeroAacTag.exe/AacGain.exe.
REM ** OggEnc2 requires OggEnc2.exe/VorbisGain.exe.
REM **
REM ** I prefer applying album gain 92dB to get a reasonable
REM ** volume for my DAP. The RG tags are still relative
REM ** to 89dB SPL, i.e. album gain will be about -3.0dB.
REM ============== Begin Main Script ==================
IF @Debug@==1 ECHO ON
REM ** Workaround for multi-processing, added by nago.
ECHO > processing[@track@].tmp
REM ** Create Disc-related tags if we have a set
SET discNumberInPath=0
REM ** Ensure that we have numeric values
SET /A discNumber = @discnumber@ + 0
SET /A totalDiscs = @totaldiscs@ + 0
REM ** If a valid disc number and total number of discs has been provided
IF %totalDiscs% LEQ 1 GOTO :end_discnumber
IF %discNumber% LEQ 0 GOTO :end_discnumber
REM ** Set tagging switches
SET Disc_Flac=-T "discnumber=@discnumber@" -T "totaldiscs=@totaldiscs@"
SET Disc_Wavpack=-w "discnumber=@discnumber@" -w "totaldiscs=@totaldiscs@"
SET Disc_MP3=--frame TPOS:"@discnumber@/@totaldiscs@"
SET Disc_NeroAac=--disk "@discnumber@/@totaldiscs@"
SET Disc_OggEnc2=-c "discnumber=@discnumber@" -c "totaldiscs=@totaldiscs@"
SET Disc_Tak=-t "discnumber=@discnumber@" -t "totaldiscs=@totaldiscs@"
REM ** Add disc number to folder path
SET trackDir=%trackDir%\Disc @discnumber@
SET discNumberInPath=1
:end_discnumber
REM ** If a disc name has been provided
IF "@discname@" EQU "" GOTO end_discname
SET discName=discname
SET discName=@%discname%@
IF "@discname@" EQU "%discName%" GOTO end_discname
REM ** Set tagging switches
SET Disc_Flac=%Disc_Flac% -T "discname=@discname@"
SET Disc_Wavpack=%Disc_Wavpack% -w "discname=@discname@"
SET Disc_MP3=%Disc_MP3% --frame "TXXX[setsubtitle]:@discname@"
SET Disc_OggEnc2=%Disc_OggEnc2% -c "discname=@discname@"
SET Disc_Tak=%Disc_Tak% -t "discname=@discname@"
REM ** Add disc name to folder path
IF %discNumberInPath%==0 SET trackDir=%trackDir%\$discname$
IF %discNumberInPath%==1 SET trackDir=%trackDir% ($discname$)
:end_discname
SET TrackDir_Flac="@TrackDir_Flac@%trackDir%"
SET TrackDir_Wavpack="@TrackDir_Wavpack@%trackDir%"
SET TrackDir_MP3="@TrackDir_MP3@%trackDir%"
SET TrackDir_AAC="@TrackDir_AAC@%trackDir%"
SET TrackDir_OGG="@TrackDir_OGG@%trackDir%"
SET TrackDir_Tak="@TrackDir_Tak@%trackDir%"
SET TrackName=@trackname@
SET have_cover=0
SET embed_cover=0
IF EXIST "@cover@" (
SET have_cover=1
SET embed_cover=@EmbedCover@
)
REM ---- Track ----
IF NOT @Flac@==1 GOTO end_flac_tracks
IF NOT EXIST %TrackDir_Flac% MKDIR %TrackDir_Flac%
PUSHD %TrackDir_Flac%
IF @various@==1 SET VA_tag=-T "album artist=@VA@"
IF %embed_cover%==1 SET Cover_tag=--picture="|image/jpeg|||@cover@"
ECHO ON
@tools@\flac.exe @Opt_Flac@ %Cover_tag% %VA_tag% %Disc_Flac% -T artist="@artist@" -T album="@album@" -T tracknumber="@track@/@numtracks@" -T title="@title@" -T date="@year@" -T genre="@genre@" -T comment="@comment@" -T encoded-by="%USERNAME%" -T encoding="Flac @Ver_Flac@ @Opt_Flac@" "@source@" -o "%TrackName%.flac"
@ECHO OFF
SET trackCueFile="$cdartist$ - $album$.cue"
IF NOT EXIST %trackCueFile% (
COPY "@albumfile@.[mg].cue" %trackCueFile%
ECHO CHCP 1252 ^| PROMPT>>update-cuesheet.bat
)
ECHO @tools@\GSAR.EXE "-s@basename@.wav" "-r%TrackName%.flac" -o %trackCueFile%>>update-cuesheet.bat
IF @Debug@==1 ECHO ON
IF %have_cover%==1 IF NOT EXIST folder.jpg COPY "@cover@" folder.jpg
POPD
:end_flac_tracks
IF NOT @Wavpack@==1 GOTO end_wavpack_tracks
IF NOT EXIST %TrackDir_Wavpack% MKDIR %TrackDir_Wavpack%
PUSHD %TrackDir_Wavpack%
IF @various@==1 SET VA_tag=-w "album artist=@VA@"
ECHO ON
@tools@\wavpack.exe @Opt_Wavpack@ %VA_tag% %Disc_Wavpack% -w artist="@artist@" -w album="@album@" -w track="@track@/@numtracks@" -w title="@title@" -w year="@year@" -w genre="@genre@" -w comment="@comment@" -w encodedby="%USERNAME%" -w encodersettings="Wavpack @Ver_Wavpack@ @Opt_Wavpack@" "@source@" "%TrackName%.wv"
@ECHO OFF
IF @Debug@==1 ECHO ON
IF %have_cover%==1 IF NOT EXIST folder.jpg COPY "@cover@" folder.jpg
TITLE @track@/@numtracks@ - "@album@"
POPD
:end_wavpack_tracks
IF NOT @Tak@==1 GOTO end_tak_tracks
IF NOT EXIST %TrackDir_Tak% MKDIR %TrackDir_Tak%
PUSHD %TrackDir_Tak%
IF @various@==1 SET VA_tag=-t "album artist=@VA@"
ECHO ON
@tools@\takc.exe -e -overwrite @Opt_Tak@ "@source@" "%TrackName%.tak"
@tools@\tag.exe %VA_tag% %Disc_Tak% -t artist="@artist@" -t album="@album@" -t track="@track@/@numtracks@" -t title="@title@" -t year="@year@" -t genre="@genre@" -t comment="@comment@" -t encodedby="%USERNAME%" -t encodersettings="TAK @Ver_Tak@ @Opt_Tak@" "%TrackName%.tak"
@ECHO OFF
IF @Debug@==1 ECHO ON
IF %have_cover%==1 IF NOT EXIST folder.jpg COPY "@cover@" folder.jpg
TITLE @track@/@numtracks@ - "@album@"
POPD
:end_tak_tracks
IF NOT @LameMP3@==1 GOTO end_lame_tracks
IF NOT EXIST %TrackDir_MP3% MKDIR %TrackDir_MP3%
PUSHD %TrackDir_MP3%
IF @various@==1 SET VA_tag=--frame "TXXX[album artist]:@VA@" --frame "TPE2:@VA@"
IF %embed_cover%==1 SET Cover_tag=--frame "APIC{3}:@cover@"
ECHO ON
@tools@\lame.exe @Opt_LameMP3@ "@source@" "%TrackName%.mp3"
@tools@\metamp3.exe %Cover_tag% %VA_tag% %Disc_MP3% --artist "@artist@" --album "@album@" --track @track@/@numtracks@ --title "@title@" --year "@year@" --genre "@genre@" --comment "@comment@" --frame TENC:"%USERNAME%" --frame TSSE:"LAME @Ver_LameMP3@ @Opt_LameMP3@" "%TrackName%.mp3"
@ECHO OFF
IF @Debug@==1 ECHO ON
IF %have_cover%==1 IF NOT EXIST folder.jpg COPY "@cover@" folder.jpg
POPD
:end_lame_tracks
IF NOT @iTunesAac@==1 GOTO end_itunes_aac_tracks
IF NOT EXIST %TrackDir_AAC% MKDIR %TrackDir_AAC%
PUSHD %TrackDir_AAC%
IF %embed_cover%==1 SET Cover_tag=-r "@cover@"
ECHO ON
@tools@\iTunesEncode.exe @Opt_iTunesAac@ -e "AAC Encoder" %Cover_tag% -x @various@ -a "@artist@" -l "@album@" -n "@track@" -m "@numtracks@" -t "@title@" -y "@year@" -g "@genre@" -c "@comment@" -i "@source@" -o "%TrackName%.m4a"
@ECHO OFF
IF @Debug@==1 ECHO ON
IF %have_cover%==1 IF NOT EXIST folder.jpg COPY "@cover@" folder.jpg
POPD
GOTO end_nero_aac_tracks
:end_itunes_aac_tracks
IF NOT @NeroAac@==1 GOTO end_nero_aac_tracks
IF NOT EXIST %TrackDir_AAC% MKDIR %TrackDir_AAC%
PUSHD %TrackDir_AAC%
IF @various@==1 SET VA_tag=--albumArtist "@VA@" --compilation true
IF %embed_cover%==1 SET Cover_tag=--artwork "@cover@"
ECHO ON
@tools@\neroAacEnc.exe @Opt_NeroAac@ -if "@source@" -of "%TrackName%.m4a"
@tools@\AtomicParsley.exe "%TrackName%.m4a" -o REACT_tmp.m4a %Cover_tag% %VA_tag% %Disc_NeroAac% --artist "@artist@" --album "@album@" --tracknum "@track@/@numtracks@" --title "@title@" --year "@year@" --genre "@genre@" --comment "@comment@" --encodingTool "neroAacEnc @Ver_NeroAac@ @Opt_NeroAac@"
@ECHO OFF
IF @Debug@==1 ECHO ON
MOVE /Y REACT_tmp.m4a "%TrackName%.m4a"
IF %have_cover%==1 IF NOT EXIST folder.jpg COPY "@cover@" folder.jpg
POPD
:end_nero_aac_tracks
IF NOT @OggEnc2@==1 GOTO end_oggenc_tracks
IF NOT EXIST %TrackDir_OGG% MKDIR %TrackDir_OGG%
PUSHD %TrackDir_OGG%
IF @various@==1 SET VA_tag=-c "album artist=@VA@"
ECHO ON
@tools@\oggenc2.exe @Opt_OggEnc2@ %VA_tag% %Disc_OggEnc2% -c artist="@artist@" -c album="@album@" -c tracknumber="@track@/@numtracks@" -c title="@title@" -c date="@year@" -c genre="@genre@" -c comment="@comment@" -c encoded-by="%USERNAME%" -c encoding="OggEnc @Ver_OggEnc2@ @Opt_OggEnc2@" "@source@" -o "%TrackName%.ogg"
@ECHO OFF
IF @Debug@==1 ECHO ON
IF %have_cover%==1 IF NOT EXIST folder.jpg COPY "@cover@" folder.jpg
POPD
:end_oggenc_tracks
REM ** Delete the source .wav
DEL "@source@"
REM ** More multiprocessing workaround --nago
DEL processing[@track@].tmp
REM ---- Post-processing ----
REM ** Scan and compute ReplayGain and add cover picture for supported formats.
REM ** NB: The following will only work if at least the last track is selected.
IF NOT @track@==@numtracks@ GOTO end_post_process
REM ** More multiprocessing. Last edit. --nago
:checktmp
IF NOT EXIST processing[*].tmp GOTO allProcsClear
ECHO Waiting for all other processes to clear...
ECHO If REACT hangs here and there are no other tracks being encoded,
ECHO please delete all processing[#].tmp files in
ECHO "@sourcedir@"
PING 1.1.1.1 -n 1 -w 10000 >NUL
GOTO checktmp
:allProcsClear
REM ** Ensure that the EAC log is available
:CheckForLog
IF NOT EXIST "@eaclog@" GOTO Pause
SET add_rg=@ReplayGain@
SET aac_enc=@NeroAac@
IF @iTunesAac@==1 SET aac_enc=1
IF NOT @ReplayGain@==1 GOTO end_RG
SET RG_MetaFlac=--add-replay-gain
SET RG_MetaMP3=--replay-gain
:end_RG
IF NOT @ApplyAlbumGain@==1 GOTO end_apply_AG
SET RG_MetaMP3=--apply-gain album@AdjustAlbumGain_dB@
SET RG_AacGain=/a /o /c /d @AdjustAlbumGain_dB@
SET add_rg=1
:end_apply_AG
REM ** Audio Formats:
IF @Flac@==1 (
PUSHD %TrackDir_Flac%
IF %add_rg%==1 @tools@\Glob.exe -v -c @tools@\metaflac.exe %RG_MetaFlac% *.flac
REM COPY /Y "@eaclog@" "EAClog.txt"
@tools@\GSAR.EXE -s%% -r%%%% -o update-cuesheet.bat
CALL update-cuesheet.bat
DEL update-cuesheet.bat
POPD
)
IF @Wavpack@==1 (
PUSHD %TrackDir_Wavpack%
IF %add_rg%==1 @tools@\wvgain.exe -a *.wv
REM COPY /Y "@eaclog@" "EAClog.txt"
POPD
)
IF @LameMP3@==1 (
PUSHD %TrackDir_MP3%
IF %add_rg%==1 @tools@\Glob.exe -v -c @tools@\metamp3.exe %RG_MetaMP3% *.mp3
REM COPY /Y "@eaclog@" "EAClog.txt"
POPD
)
IF %aac_enc%==1 (
PUSHD %TrackDir_AAC%
IF %add_rg%==1 @tools@\aacgain.exe %RG_AacGain% *.m4a > "gainlog.txt"
REM COPY /Y "@eaclog@" "EAClog.txt"
POPD
)
IF @OggEnc2@==1 (
PUSHD %TrackDir_OGG%
IF %add_rg%==1 @tools@\vorbisgain.exe -a *.ogg
REM COPY /Y "@eaclog@" "EAClog.txt"
POPD
)
REM ** Cleanup
DEL "@eaclog@"
DEL "@albumfile@.[*].cue"
DEL "@cover@"
:end_post_process
REM ================ End Main Script ===================
IF @Debug@==1 (
PAUSE
EXIT
)
REM ** Delete this .bat file:
DEL %0 &EXIT
GOTO :EOF
REM ** Pause for 2000 milliseconds and return to :CheckForLog
:Pause
@ECHO Waiting for EAC log file...
PING 1.1.1.1 -n 1 -w 2000 >NUL
GOTO CheckForLog